
function s = intTrap(f,a,b,n)
    X=linspace(a,b,n+1)
    s=0
    for k=0:n-1
       s=s+(f(X(k+1))+f(X(k+2)))/2
    end
    s=s*(b-a)/n
endfunction

function s = intSimp(f,a,b,n)
    // Dans la méthode de simpson mieux vaut considérer le cas où n est pair
    if modulo(n,2) == 1
        n=n+1
    end
    s=0
    for i=1:(n-1)
        if modulo(i,2) == 0
            s = s + 2*f(a+i*(b-a)/n)
        else
            s = s + 4*f(a+i*(b-a)/n)
        end
    end
    s=(b-a)/(3*n) * (f(a) + f(b) + s)
endfunction


function l = longCf(f,a,b,n)
    T=sqrt(ones(1,n+1)+derive(f,a,b,n).^2)
    l=0
    for k=0:n-1
       l=l+(T(k+1)+T(k+2))/2
    end
    l=l*(b-a)/n
endfunction

// L'algo naif pour mesure la longueur d'une courbe est de calculer la distance entre les points (x_k,f(x_k)) et (x_k+1,f(x_{k+1})) pour tous les k et d'en faire la somme
function l = longCfNaif(f,a,b,n)
    X=linspace(a,b,n+1)
    h=(b-a)/n
    l=0
    for k=1:n
       l=l+sqrt(h^2+(f(X(k+1))-f(X(k)))^2)
    end
endfunction
